efl/src/lib/ecore_audio/ecore_audio_in.eo

class Ecore.Audio.In (Ecore.Audio)
{
   [[Ecore Audio input object.]]
   eo_prefix: ecore_audio_obj_in;
   event_prefix: ecore_audio_in;
   data: Ecore_Audio_Input;
   methods {
      @property speed {
         [[Playback speed of the input.

           @since 1.8
         ]]
         set {
         }
         get {
         }
         values {
            speed: double; [[The speed, 1.0 is the default]]
         }
      }
      @property samplerate {
         [[Sample-rate of the input

           @since 1.8
         ]]
         set {
         }
         get {
         }
         values {
            samplerate: int; [[The samplerate in Hz]]
         }
      }
      @property channels {
         [[Amount of channels the input has

           @since 1.8
         ]]
         set {
         }
         get {
         }
         values {
            channels: int; [[The number of channels]]
         }
      }
      @property preloaded @virtual_pure {
         [[Preloaded state of the input

           @since 1.8
         ]]
         set {
         }
         get {
         }
         values {
            preloaded: bool; [[true if the input should be cached, false otherwise]]
         }
      }
      @property looped {
         [[Looped state of the input

           If the input is looped and reaches the end it will start from the
           beginning again. At the same time the event
           \@ref ECORE_AUDIO_EV_IN_LOOPED will be emitted

           @since 1.8
         ]]
         set {
         }
         get {
         }
         values {
            looped: bool; [[true if the input should be looped, false otherwise]]
         }
      }
      @property length {
         [[Length of the input

           This function is only implemented by some classes
           (i.e. ECORE_AUDIO_OBJ_IN_TONE_CLASS)

           @since 1.8
         ]]
         set @virtual_pure {
         }
         get {
         }
         values {
            length: double; [[The length of the input in seconds]]
         }
      }
      @property output {
         get {
            [[Get the output that this input is attached to

              @since 1.8
            ]]
         }
         values {
            output: Ecore.Audio; [[The output]] /* FIXME-cyclic Should be Ecore.Audio.Out */
         }
      }
      @property remaining {
         get {
            [[Get the remaining time of the input

              @since 1.8
            ]]
         }
         values {
            remaining: double; [[The amount of time in seconds left to play]]
         }
      }
      read {
         [[Read from the input

           @since 1.8
         ]]
         return: ssize; [[The amount of samples written to buf]]
         params {
            @in buf: void_ptr; [[The buffer to read into]]
            @in len: size; [[The amount of samples to read]]
         }
      }
      read_internal {
         [[Internal read function

           @since 1.8
         ]]
         return: ssize; [[The amount of samples written to buf]]
         params {
            @in buf: void_ptr; [[The buffer to read into]]
            @in len: size; [[The amount of samples to read]]
         }
      }
      seek @virtual_pure {
         [[Seek within the input

           @since 1.8
         ]]
         return: double; [[The current absolute position in seconds within
                           the input]]
         params {
            @in offs: double; [[The offset in seconds]]
            @in mode: int; [[The seek mode. Is absolute with SEEK_SET,
                             relative to the current position with SEEK_CUR
                             and relative to the end with SEEK_END.]]
         }
      }
   }
   implements {
      Efl.Object.constructor;
      Efl.Object.destructor;
      Ecore.Audio.vio_set;
   }
   events {
      in,looped; [[Called when an input has looped.]]
      in,stopped; [[Called when an input has stopped playing.]]
      in,samplerate,changed; [[Called when the input samplerate has changed.]]
   }
}