extra! Let there be meson!

extra also join the meson hype train!

doc/meson.build

@@ -0,0 +1,6 @@
+configure_file(
+  input : 'extra.1.in',
+  output : 'extra.1',
+  install_dir : join_paths(get_option('prefix'), 'share/doc/extra/'),
+  configuration : config_h
+)

meson.build

@@ -0,0 +1,30 @@
+project(
+  'extra', 'c',
+  version : '0.0.1',
+  default_options: [ 'c_std=gnu99', 'warning_level=2' ],
+  meson_version : '>= 0.40.0')
+
+add_global_arguments('-DHAVE_CONFIG_H=1', language: 'c')
+
+config_h = configuration_data()
+config_h.set_quoted('PACKAGE'          , meson.project_name())
+config_h.set_quoted('PACKAGE_VERSION'  , meson.project_version())
+config_h.set_quoted('PACKAGE_URL'      , 'https://www.enlightenment.org')
+config_h.set_quoted('PACKAGE_TARNAME'  , meson.project_name())
+config_h.set_quoted('PACKAGE_BUGREPORT', 'enlightenment-devel@lists.sourceforge.net')
+config_h.set_quoted('PACKAGE_STRING'   , meson.project_name() + ' ' + meson.project_version())
+config_h.set_quoted('PACKAGE_NAME'     , meson.project_name())
+
+elm = dependency('elementary')
+
+top_inc = include_directories('.')
+
+subdir('po')
+subdir('src')
+subdir('doc')
+
+configure_file(
+  output : 'config.h',
+  install : false,
+  configuration: config_h
+)

po/meson.build

@@ -0,0 +1,5 @@
+i18n = import('i18n')
+i18n.gettext('extra')
+
+config_h.set('ENABLE_NLS', 1)
+config_h.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))

src/bin/meson.build

@@ -0,0 +1,17 @@
+files = [
+  'extra_main.c',
+  'extra_util.c',
+  'extra_util.h',
+  'extra_background_selector.c',
+  'extra_theme_selector.c',
+  'extra_private.h',
+  'gettext.h'
+]
+
+executable('extra',
+  files,
+  dependencies : elm,
+  include_directories : top_inc,
+  link_with : extra_lib,
+  install : true
+)

src/lib/meson.build

@@ -0,0 +1,15 @@
+files = [
+  'extra.c',
+  'extra.h',
+  'extra_api_helper.c',
+  'extra_private.h',
+  'jsmn/jsmn.c',
+  'jsmn/jsmn.h'
+]
+
+extra_lib = library('extra',
+  files,
+  dependencies : elm,
+  include_directories : top_inc,
+  install : true
+)

src/meson.build

@@ -0,0 +1,4 @@
+subdir('lib')
+subdir('bin')
+
+#subdir('tests')