summaryrefslogtreecommitdiff
path: root/efl/elementary/diskselector.pyx
blob: ecc6aafc002978bc405732d35f323be6c71e1934 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
# Copyright (C) 2007-2015 various contributors (see AUTHORS)
#
# This file is part of Python-EFL.
#
# Python-EFL is free software; you can redistribute it and/or
# modify it under the terms of the GNU Lesser General Public
# License as published by the Free Software Foundation; either
# version 3 of the License, or (at your option) any later version.
#
# Python-EFL is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
# Lesser General Public License for more details.
#
# You should have received a copy of the GNU Lesser General Public License
# along with this Python-EFL.  If not, see <http://www.gnu.org/licenses/>.

"""

:mod:`diskselector` Module
##########################

.. image:: /images/diskselector-preview.png


Widget description
==================

A diskselector is a kind of list widget. It scrolls horizontally,
and can contain label and icon objects. Three items are displayed
with the selected one in the middle.

It can act like a circular list with round mode and labels can be
reduced for a defined length for side items.


Emitted signals
===============

- ``selected`` - when item is selected, i.e. scroller stops.
- ``clicked`` - This is called when a user clicks an item
- ``scroll,anim,start`` - scrolling animation has started
- ``scroll,anim,stop`` - scrolling animation has stopped
- ``scroll,drag,start`` - dragging the diskselector has started
- ``scroll,drag,stop`` - dragging the diskselector has stopped
- ``focused`` - When the diskselector has received focus. (since 1.8)
- ``unfocused`` - When the diskselector has lost focus. (since 1.8)

.. note:: The ``scroll,anim,*`` and ``scroll,drag,*`` signals are only emitted
          by user intervention.

Layout content parts
====================

- ``icon`` - An icon in the diskselector item


Layout text parts
=================

- ``default`` - Label of the diskselector item


Scrollable Interface
====================

This widget supports the scrollable interface.

If you wish to control the scrolling behaviour using these functions,
inherit both the widget class and the
:py:class:`~efl.elementary.scroller.Scrollable` class
using multiple inheritance, for example::

    class ScrollableGenlist(Genlist, Scrollable):
        def __init__(self, canvas, *args, **kwargs):
            Genlist.__init__(self, canvas)


Inheritance diagram
===================

.. inheritance-diagram:: efl.elementary.diskselector
    :parts: 2

"""

from cpython cimport PyUnicode_AsUTF8String
from libc.stdint cimport uintptr_t

from efl.eo cimport _object_mapping_register
from efl.evas cimport Object as evasObject
from object cimport Object
from object_item cimport ObjectItem, _object_item_callback, \
    _object_item_to_python, _object_item_list_to_python, _object_item_callback2

from efl.utils.deprecated cimport DEPRECATED
from scroller cimport elm_scroller_policy_get, elm_scroller_policy_set, \
    elm_scroller_bounce_get, elm_scroller_bounce_set, Elm_Scroller_Policy

cdef _cb_object_item_conv(void *addr):
    return _object_item_to_python(<Elm_Object_Item *>addr)

# def _cb_object_item_conv(uintptr_t addr):
#     cdef Elm_Object_Item *it = <Elm_Object_Item *>addr
#     return _object_item_to_python(it)


cdef class DiskselectorItem(ObjectItem):
    """

    An item for the :py:class:`Diskselector` widget.

    A new item will be created and appended to the diskselector, i.e.,
    will be set as last item. Also, if there is no selected item, it will
    be selected. This will always happens for the first appended item.

    If no icon is set, label will be centered on item position, otherwise
    the icon will be placed at left of the label, that will be shifted
    to the right.

    Items created with this method can be deleted with
    :py:meth:`~efl.elementary.object_item.ObjectItem.delete`.

    If a function is passed as argument, it will be called every time
    this item is selected, i.e., the user stops the diskselector with
    this item on center position.

    Simple example (with no function callback or data associated)::

        disk = Diskselector(win)
        ic = Icon(win, file="path/to/image", resizable=(True, True))
        disk.item_append("label", ic)

    .. seealso::
        :py:meth:`~efl.elementary.object_item.ObjectItem.delete`
        :py:meth:`Diskselector.clear`
        :py:class:`~efl.elementary.image.Image`

    """

    cdef:
        bytes label
        evasObject icon

    def __init__(self, label=None, evasObject icon=None, callback=None,
        cb_data=None, *args, **kargs):
        """DiskselectorItem(...)

        :param label: The label of the diskselector item.
        :type label: string
        :param icon: The icon object to use at left side of the item. An
            icon can be any Evas object, but usually it is an
            :py:class:`~efl.elementary.icon.Icon`.
        :type icon: :py:class:`~efl.evas.Object`
        :param callback: The function to call when the item is selected.
        :type callback: callable
        :param cb_data: User data for the callback function
        :param \**kwargs: All the remaining keyword arguments are interpreted
                          as properties of the instance

        """
        if callback is not None:
            if not callable(callback):
                raise TypeError("callback is not callable")

        if isinstance(label, unicode): label = PyUnicode_AsUTF8String(label)
        self.label = label
        self.icon = icon
        self.cb_func = callback
        self.cb_data = cb_data
        self.args = args
        self.kwargs = kargs

    def append_to(self, Diskselector diskselector):
        """Appends a new item to the diskselector object.

        :return: The created item or ``None`` upon failure.
        :rtype: :py:class:`DiskselectorItem`

        """
        cdef Evas_Smart_Cb cb = NULL

        if self.cb_func is not None:
            cb = _object_item_callback2

        item = elm_diskselector_item_append(diskselector.obj,
            <const char *>self.label if self.label is not None else NULL,
            self.icon.obj if self.icon is not None else NULL,
            cb, <void*>self)

        if item == NULL:
            raise RuntimeError("The item could not be added to the widget.")

        self._set_obj(item)
        self._set_properties_from_keyword_args(self.kwargs)
        return self

    property selected:
        """The selected state of an item.

        This sets the selected state of the given item.
        ``True`` for selected, ``False`` for not selected.

        If a new item is selected the previously selected will be unselected.
        Previously selected item can be fetched from the property
        :py:attr:`Diskselector.selected_item`.

        If the item is unselected, the first item of diskselector will
        be selected.

        Selected items will be visible on center position of diskselector.
        So if it was on another position before selected, or was invisible,
        diskselector will animate items until the selected item reaches center
        position.

        .. seealso:: :py:attr:`Diskselector.selected_item`

        :type: bool

        """
        def __set__(self, selected):
            elm_diskselector_item_selected_set(self.item, selected)
        def __get__(self):
            return bool(elm_diskselector_item_selected_get(self.item))

    property prev:
        """Get the item before ``item`` in diskselector.

        The list of items follows append order. So it will return item appended
        just before ``item`` and that wasn't deleted.

        If it is the first item, ``None`` will be returned.
        First item can be get by :py:attr:`Diskselector.first_item`.

        .. seealso::
            :py:func:`Diskselector.item_append()`
            :py:attr:`Diskselector.items`

        :type: DiskselectorItem

        """
        def __get__(self):
            cdef Elm_Object_Item *it = elm_diskselector_item_prev_get(self.item)
            return _object_item_to_python(it)

    property next:
        """Get the item after ``item`` in diskselector.

        The list of items follows append order. So it will return item appended
        just after ``item`` and that wasn't deleted.

        If it is the last item, ``None`` will be returned.
        Last item can be get by :py:attr:`Diskselector.last_item`.

        .. seealso::
            :py:func:`Diskselector.item_append()`
            :py:attr:`Diskselector.items`

        :type: DiskselectorItem

        """
        def __get__(self):
            cdef Elm_Object_Item *it = elm_diskselector_item_next_get(self.item)
            return _object_item_to_python(it)

cdef class Diskselector(Object):
    """

    This is the class that actually implements the widget.

    """

    def __init__(self, evasObject parent, *args, **kwargs):
        """Diskselector(...)

        :param parent: The parent object
        :type parent: :py:class:`efl.evas.Object`
        :param \**kwargs: All the remaining keyword arguments are interpreted
                          as properties of the instance

        """
        self._set_obj(elm_diskselector_add(parent.obj))
        self._set_properties_from_keyword_args(kwargs)

    property round_enabled:
        """Enable or disable round mode.

        Disabled by default. If round mode is enabled the items list will
        work like a circular list, so when the user reaches the last item,
        the first one will popup.

        :type: bool

        """
        def __set__(self, enabled):
            elm_diskselector_round_enabled_set(self.obj, enabled)
        def __get__(self):
            return bool(elm_diskselector_round_enabled_get(self.obj))

    property side_text_max_length:
        """The side labels max length.

        Length is the number of characters of items' label that will be
        visible when it's set on side positions. It will just crop
        the string after defined size. E.g.:

        An item with label "January" would be displayed on side position as
        "Jan" if max length is set to 3, or "Janu", if this property
        is set to 4.

        When it's selected, the entire label will be displayed, except for
        width restrictions. In this case label will be cropped and "..."
        will be concatenated.

        Default side label max length is 3.

        This property will be applied over all items, included before or
        later this function call.

        :type: int

        """
        def __get__(self):
            return elm_diskselector_side_text_max_length_get(self.obj)
        def __set__(self, length):
            elm_diskselector_side_text_max_length_set(self.obj, length)

    property display_item_num:
        """The number of items to be displayed.

        Default value is 3, and also it's the minimum. If ``num`` is less
        than 3, it will be set to 3.

        Also, it can be set on theme, using data item ``display_item_num``
        on group "elm/diskselector/item/X", where X is style set.
        E.g.::

            group { name: "elm/diskselector/item/X";
                data {
                    item: "display_item_num" "5";
                }

        :type: int

        """
        def __set__(self, num):
            elm_diskselector_display_item_num_set(self.obj, num)
        def __get__(self):
            return elm_diskselector_display_item_num_get(self.obj)

    def clear(self):
        """Remove all diskselector's items.

        .. seealso::
            :py:meth:`~efl.elementary.object_item.ObjectItem.delete()`
            :py:meth:`item_append`

        """
        elm_diskselector_clear(self.obj)

    property items:
        """Get a list of all the diskselector items.

        .. seealso::
            :py:meth:`item_append`
            :py:meth:`~efl.elementary.object_item.ObjectItem.delete()`
            :py:meth:`clear`

        :type: list of :py:class:`DiskselectorItem`

        """
        def __get__(self):
            return _object_item_list_to_python(elm_diskselector_items_get(self.obj))

    def item_append(self, label, evasObject icon = None, callback = None,
        *args, **kwargs):
        """A constructor for :py:class:`DiskselectorItem`

        :see: :func:`DiskselectorItem.append_to`

        """
        cdef:
            Elm_Object_Item *item
            Evas_Smart_Cb cb = NULL
            DiskselectorItem ret = DiskselectorItem.__new__(DiskselectorItem)

        if callback is not None and callable(callback):
            cb = _object_item_callback

        if isinstance(label, unicode): label = PyUnicode_AsUTF8String(label)

        item = elm_diskselector_item_append(self.obj,
            <const char *>label if label is not None else NULL,
            icon.obj if icon is not None else NULL,
            cb, <void*>ret)

        if item != NULL:
            ret._set_obj(item)
            ret.cb_func = callback
            ret.args = args
            ret.kwargs = kwargs
            return ret
        else:
            return None

    property selected_item:
        """Get the selected item.

        The selected item can be unselected with function
        :py:attr:`DiskselectorItem.selected`, and the first item of diskselector
        will be selected.

        The selected item always will be centered on diskselector, with full
        label displayed, i.e., max length set to side labels won't apply on
        the selected item. More details on
        :py:attr:`side_text_max_length`.

        :type: :py:class:`DiskselectorItem`

        """
        def __get__(self):
            return _object_item_to_python(elm_diskselector_selected_item_get(self.obj))

    property first_item:
        """Get the first item of the diskselector.

        The list of items follows append order. So it will return the first
        item appended to the widget that wasn't deleted.

        .. seealso:: :py:func:`item_append` :py:attr:`items`

        :type: :py:class:`DiskselectorItem`

        """
        def __get__(self):
            return _object_item_to_python(elm_diskselector_first_item_get(self.obj))

    property last_item:
        """Get the last item of the diskselector.

        The list of items follows append order. So it will return last first
        item appended to the widget that wasn't deleted.

        .. seealso:: :py:func:`item_append` :py:attr:`items`

        :type: :py:class:`DiskselectorItem`

        """
        def __get__(self):
            return _object_item_to_python(elm_diskselector_last_item_get(self.obj))

    def callback_selected_add(self, func, *args, **kwargs):
        """When item is selected, i.e. scroller stops."""
        self._callback_add_full("selected", _cb_object_item_conv, func, args, kwargs)

    def callback_selected_del(self, func):
        self._callback_del_full("selected", _cb_object_item_conv, func)

    def callback_clicked_add(self, func, *args, **kwargs):
        """This is called when a user clicks an item

        .. versionadded:: 1.8
        """
        self._callback_add_full("clicked", _cb_object_item_conv, func, args, kwargs)

    def callback_clicked_del(self, func):
        self._callback_del_full("clicked", _cb_object_item_conv, func)

    def callback_scroll_anim_start_add(self, func, *args, **kwargs):
        """Scrolling animation has started."""
        self._callback_add("scroll,anim,start", func, args, kwargs)

    def callback_scroll_anim_start_del(self, func):
        self._callback_del("scroll,anim,start", func)

    def callback_scroll_anim_stop_add(self, func, *args, **kwargs):
        """Scrolling animation has stopped."""
        self._callback_add("scroll,anim,stop", func, args, kwargs)

    def callback_scroll_anim_stop_del(self, func):
        self._callback_del("scroll,anim,stop", func)

    def callback_scroll_drag_start_add(self, func, *args, **kwargs):
        """Dragging the diskselector has started."""
        self._callback_add("scroll,drag,start", func, args, kwargs)

    def callback_scroll_drag_start_del(self, func):
        self._callback_del("scroll,drag,start", func)

    def callback_scroll_drag_stop_add(self, func, *args, **kwargs):
        """Dragging the diskselector has stopped."""
        self._callback_add("scroll,drag,stop", func, args, kwargs)

    def callback_scroll_drag_stop_del(self, func):
        self._callback_del("scroll,drag,stop", func)

    def callback_focused_add(self, func, *args, **kwargs):
        """When the diskselector has received focus.

        .. versionadded:: 1.8
        """
        self._callback_add("focused", func, args, kwargs)

    def callback_focused_del(self, func):
        self._callback_del("focused", func)

    def callback_unfocused_add(self, func, *args, **kwargs):
        """When the diskselector has lost focus.

        .. versionadded:: 1.8
        """
        self._callback_add("unfocused", func, args, kwargs)

    def callback_unfocused_del(self, func):
        self._callback_del("unfocused", func)


    property scroller_policy:
        """

        .. deprecated:: 1.8
            You should combine with Scrollable class instead.

        """
        def __get__(self):
            return self.scroller_policy_get()

        def __set__(self, value):
            cdef Elm_Scroller_Policy policy_h, policy_v
            policy_h, policy_v = value
            self.scroller_policy_set(policy_h, policy_v)

    @DEPRECATED("1.8", "You should combine with Scrollable class instead.")
    def scroller_policy_set(self, policy_h, policy_v):
        elm_scroller_policy_set(self.obj, policy_h, policy_v)
    @DEPRECATED("1.8", "You should combine with Scrollable class instead.")
    def scroller_policy_get(self):
        cdef Elm_Scroller_Policy policy_h, policy_v
        elm_scroller_policy_get(self.obj, &policy_h, &policy_v)
        return (policy_h, policy_v)

    property bounce:
        """

        .. deprecated:: 1.8
            You should combine with Scrollable class instead.

        """
        def __get__(self):
            return self.bounce_get()
        def __set__(self, value):
            cdef Eina_Bool h, v
            h, v = value
            self.bounce_set(h, v)

    @DEPRECATED("1.8", "You should combine with Scrollable class instead.")
    def bounce_set(self, h, v):
        elm_scroller_bounce_set(self.obj, h, v)
    @DEPRECATED("1.8", "You should combine with Scrollable class instead.")
    def bounce_get(self):
        cdef Eina_Bool h, v
        elm_scroller_bounce_get(self.obj, &h, &v)
        return (h, v)


_object_mapping_register("Elm_Diskselector", Diskselector)