aboutsummaryrefslogtreecommitdiffstats
path: root/efl/elementary/slider.pxi
blob: 28b46bde17c90d2508a0d0edfc6634dd10d487f6 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
# Copyright (C) 2007-2016 various contributors (see AUTHORS)
#
# This file is part of Python-EFL.
#
# Python-EFL is free software; you can redistribute it and/or
# modify it under the terms of the GNU Lesser General Public
# License as published by the Free Software Foundation; either
# version 3 of the License, or (at your option) any later version.
#
# Python-EFL is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
# Lesser General Public License for more details.
#
# You should have received a copy of the GNU Lesser General Public License
# along with this Python-EFL.  If not, see <http://www.gnu.org/licenses/>.

include "slider_cdef.pxi"

cdef class Slider(LayoutClass):
    """

    This is the class that actually implements the widget.

    """

    def __init__(self, evasObject parent, *args, **kwargs):
        """Slider(...)

        :param parent: The parent object
        :type parent: :py:class:`efl.evas.Object`
        :param \**kwargs: All the remaining keyword arguments are interpreted
                          as properties of the instance

        """
        self._set_obj(elm_slider_add(parent.obj))
        self._set_properties_from_keyword_args(kwargs)

    property span_size:
        """The (exact) length of the bar region of a given slider widget.

        This property reflects the minimum width (when in horizontal mode)
        or height (when in vertical mode) of the actual bar area of the
        slider. This in turn affects the object's minimum size. Use this
        when you're not setting other size hints expanding on the given
        direction (like weight and alignment hints) and you would like it to
        have a specific size.

        .. note:: Icon, end, label, indicator and unit text around the object
            will require their own space, which will make the object to
            require more the ``size``, actually.

        :type: int

        """
        def __get__(self):
            return elm_slider_span_size_get(self.obj)

        def __set__(self, size):
            elm_slider_span_size_set(self.obj, size)

    def span_size_set(self, size):
        elm_slider_span_size_set(self.obj, size)
    def span_size_get(self):
        return elm_slider_span_size_get(self.obj)

    property unit_format:
        """The format string for the unit label.

        Unit label is displayed all the time, if set, after slider's bar.
        In horizontal mode, at right and in vertical mode, at bottom.

        If ``None``, unit label won't be visible. If not it sets the format
        string for the label text. To the label text is provided a floating point
        value, so the label text can display up to 1 floating point value.
        Note that this is optional.

        Use a format string such as ``"%1.2f meters"`` for example, and it will
        display values like: "3.14 meters" for a value equal to 3.14159.

        Default is unit label disabled.

        :type: unicode

        """
        def __get__(self):
            return _ctouni(elm_slider_unit_format_get(self.obj))

        def __set__(self, unit_format):
            if isinstance(unit_format, unicode): unit_format = PyUnicode_AsUTF8String(unit_format)
            elm_slider_unit_format_set(self.obj,
                <const char *>unit_format if unit_format is not None else NULL)

    def unit_format_set(self, unit_format):
        if isinstance(unit_format, unicode): unit_format = PyUnicode_AsUTF8String(unit_format)
        elm_slider_unit_format_set(self.obj,
            <const char *>unit_format if unit_format is not None else NULL)
    def unit_format_get(self):
        return _ctouni(elm_slider_unit_format_get(self.obj))

    property indicator_format:
        """The format string for the indicator label.

        The slider may display its value somewhere else then unit label, for
        example, above the slider knob that is dragged around. This function
        sets the format string used for this.

        If ``None``, indicator label won't be visible. If not it sets the
        format string for the label text. To the label text is provided a
        floating point value, so the label text can display up to 1 floating
        point value. Note that this is optional.

        Use a format string such as ``"%1.2f meters"`` for example, and it will
        display values like: "3.14 meters" for a value equal to 3.14159.

        Default is indicator label disabled.

        :type: unicode

        """
        def __get__(self):
            return _ctouni(elm_slider_indicator_format_get(self.obj))

        def __set__(self, ind_format):
            if isinstance(ind_format, unicode): ind_format = PyUnicode_AsUTF8String(ind_format)
            elm_slider_indicator_format_set(self.obj,
                <const char *>ind_format if ind_format is not None else NULL)

    def indicator_format_set(self, ind_format):
        if isinstance(ind_format, unicode): ind_format = PyUnicode_AsUTF8String(ind_format)
        elm_slider_indicator_format_set(self.obj,
            <const char *>ind_format if ind_format is not None else NULL)
    def indicator_format_get(self):
        return _ctouni(elm_slider_indicator_format_get(self.obj))

    #TODO: def indicator_format_function_set(self, func, free_func)
    #
    # Since we can't use a custom python function in the callback,
    # make a list of common formatting functions and allow to select
    # one of them.
    #
#~         """Set the format function pointer for the indicator label
#~
#~         Set the callback function to format the indicator string.
#~
#~         .. seealso:: :py:attr:`indicator_format_set()` for more info on how this works.
#~
#~         :param func: The indicator format function.
#~         :type func: function
#~         :param free_func: The freeing function for the format string.
#~         :type free_func: function
#~
#~         """
        #elm_slider_indicator_format_function_set(self.obj, char(*func)(double val), void (*free_func)(charstr))

    #TODO: def units_format_function_set(self, func, free_func)
    #
    # Since we can't use a custom python function in the callback,
    # make a list of common formatting functions and allow to select
    # one of them.
    #
#~         """Set the format function pointer for the units label
#~
#~         Set the callback function to format the units string.
#~
#~         .. seealso:: :py:attr:`units_format_set()` for more info on how this works.
#~
#~         :param func: The units format function.
#~         :type func: function
#~         :param free_func: The freeing function for the format string.
#~         :type free_func: function
#~
#~         """
        #elm_slider_units_format_function_set(self.obj, char(*func)(double val), void (*free_func)(charstr))

    property horizontal:
        """The orientation of a given slider widget.

        This property reflects how your slider is to be disposed: vertically
        or horizontally.

        By default it's displayed horizontally.

        :type: bool

        """
        def __get__(self):
            return bool(elm_slider_horizontal_get(self.obj))

        def __set__(self, horizontal):
            elm_slider_horizontal_set(self.obj, horizontal)

    def horizontal_set(self, horizontal):
        elm_slider_horizontal_set(self.obj, horizontal)
    def horizontal_get(self):
        return bool(elm_slider_horizontal_get(self.obj))

    property min_max:
        """The minimum and maximum values for the slider.

        If actual value is less than ``min``, it will be updated to ``min``. If it
        is bigger then ``max``, will be updated to ``max``. Actual value can be
        get with :py:attr:`value`.

        By default, min is equal to 0.0, and max is equal to 1.0.

        .. warning:: Maximum must be greater than minimum, otherwise behavior
            is undefined.

        :type: (float, float)

        """
        def __get__(self):
            cdef double min, max
            elm_slider_min_max_get(self.obj, &min, &max)
            return (min, max)

        def __set__(self, value):
            min, max = value
            elm_slider_min_max_set(self.obj, min, max)

    def min_max_set(self, min, max):
        elm_slider_min_max_set(self.obj, min, max)
    def min_max_get(self):
        cdef double min, max
        elm_slider_min_max_get(self.obj, &min, &max)
        return (min, max)

    property range_enabled:
        """Enables the range ability.

        This enables two indicators in slider, so that the user can select
        a range, not just a single value.

        :type: bool

        .. versionadded:: 1.18

        """
        def __get__(self):
            return bool(elm_slider_range_enabled_get(self.obj))
        def __set__(self, bint enabled):
            elm_slider_range_enabled_set(self.obj, enabled)

    def range_enabled_set(self, bint enabled):
        elm_slider_range_enabled_set(self.obj, enabled)
    def range_enabled_get(self):
        return bool(elm_slider_range_enabled_get(self.obj))

    property range:
        """The values of the two indicators.

        :type: (float, float)

        .. versionadded:: 1.18

        """
        def __get__(self):
            cdef double fr, to
            elm_slider_range_get(self.obj, &fr, &to)
            return (fr, to)

        def __set__(self, value):
            fr, to = value
            elm_slider_range_set(self.obj, fr, to)

    def range_set(self, double fr, double to):
        elm_slider_range_set(self.obj, fr, to)
    def range_get(self):
        cdef double fr, to
        elm_slider_range_get(self.obj, &fr, &to)
        return (fr, to)

    property value:
        """The value displayed in the slider.

        Value will be presented on the unit label following format specified
        with :py:attr:`unit_format` and on indicator with
        :py:attr:`indicator_format`.

        .. warning:: The value must to be between min and max values. These
            values are set by :py:attr:`min_max`.

        .. seealso::
            :py:attr:`unit_format`
            :py:attr:`indicator_format`
            :py:attr:`min_max`

        :type: float

        """
        def __get__(self):
            return elm_slider_value_get(self.obj)

        def __set__(self, value):
            elm_slider_value_set(self.obj, value)

    def value_set(self, value):
        elm_slider_value_set(self.obj, value)
    def value_get(self):
        return elm_slider_value_get(self.obj)

    property inverted:
        """Invert a given slider widget's displaying values order

        A slider may be **inverted**, in which state it gets its
        values inverted, with high vales being on the left or top and
        low values on the right or bottom, as opposed to normally have
        the low values on the former and high values on the latter,
        respectively, for horizontal and vertical modes.

        :type: bool

        """
        def __get__(self):
            return bool(elm_slider_inverted_get(self.obj))

        def __set__(self, inverted):
            elm_slider_inverted_set(self.obj, inverted)

    def inverted_set(self, inverted):
        elm_slider_inverted_set(self.obj, inverted)
    def inverted_get(self):
        return bool(elm_slider_inverted_get(self.obj))

    property indicator_show:
        """Whether to enlarge slider indicator (augmented knob) or not.

        By default, indicator will be bigger while dragged by the user.

        .. warning:: It won't display values set
            with :py:attr:`indicator_format` if you disable indicator.

        :type: bool

        """
        def __get__(self):
            return bool(elm_slider_indicator_show_get(self.obj))

        def __set__(self, show):
            elm_slider_indicator_show_set(self.obj, show)

    def indicator_show_set(self, show):
        elm_slider_indicator_show_set(self.obj, show)
    def indicator_show_get(self):
        return bool(elm_slider_indicator_show_get(self.obj))

    property indicator_visible_mode:
        """The visible mode of indicator

        :type: :ref:`Elm_Slider_Indicator_Visible_Mode`

        .. versionadded:: 1.14

        """
        def __set__(self, indicator_visible_mode):
            elm_slider_indicator_visible_mode_set(self.obj, indicator_visible_mode)
        def __get__(self):
            return elm_slider_indicator_visible_mode_get(self.obj)

    def indicator_visible_mode_set(self, indicator_visible_mode):
        elm_slider_indicator_visible_mode_set(self.obj, indicator_visible_mode)
    def indicator_visible_mode_get(self):
        return elm_slider_indicator_visible_mode_get(self.obj)

    property indicator_show_on_focus:
        """Whether to show the indicator of the slider on focus.

        :type: bool

        .. versionadded: 1.18

        """
        def __get__(self):
            return bool(elm_slider_indicator_show_on_focus_get(self.obj))

        def __set__(self, bint show):
            elm_slider_indicator_show_on_focus_set(self.obj, show)

    def indicator_show_on_focus_set(self, bint show):
        elm_slider_indicator_show_on_focus_set(self.obj, show)
    def indicator_show_on_focus_get(self):
        return bool(elm_slider_indicator_show_on_focus_get(self.obj))

    property step:
        """The step by which slider indicator will move.

        This value is used when draggable object is moved automatically i.e., in
        case of key event when up/down/left/right key is pressed or in case when
        accessibility is set and flick event is used to inc/dec slider values.
        By default step value is equal to 0.05.

        :type: double

        .. versionadded:: 1.8

        """
        def __set__(self, double step):
            elm_slider_step_set(self.obj, step)

        def __get__(self):
            return elm_slider_step_get(self.obj)

    def step_set(self, double step):
        elm_slider_step_set(self.obj, step)
    def step_get(self):
        return elm_slider_step_get(self.obj)

    def callback_changed_add(self, func, *args, **kwargs):
        """Whenever the slider value is changed by the user."""
        self._callback_add("changed", func, args, kwargs)

    def callback_changed_del(self, func):
        self._callback_del("changed", func)

    def callback_slider_drag_start_add(self, func, *args, **kwargs):
        """Dragging the slider indicator around has started."""
        self._callback_add("slider,drag,start", func, args, kwargs)

    def callback_slider_drag_start_del(self, func):
        self._callback_del("slider,drag,start", func)

    def callback_slider_drag_stop_add(self, func, *args, **kwargs):
        """Dragging the slider indicator around has stopped."""
        self._callback_add("slider,drag,stop", func, args, kwargs)

    def callback_slider_drag_stop_del(self, func):
        self._callback_del("slider,drag,stop", func)

    def callback_delay_changed_add(self, func, *args, **kwargs):
        """A short time after the value is changed by the user. This will be
        called only when the user stops dragging for a very short period or
        when they release their finger/mouse, so it avoids possibly
        expensive reactions to the value change.

        """
        self._callback_add("delay,changed", func, args, kwargs)

    def callback_delay_changed_del(self, func):
        self._callback_del("delay,changed", func)


_object_mapping_register("Elm_Slider", Slider)