summaryrefslogtreecommitdiff
path: root/pkgbuild/PKGBUILD.in
blob: d7c7a8b6b1e86a5ef7568586624829e84aea8b06 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
# Maintainer: Enlightenment Developers <enlightenment-devel@enlightenment.org>
pkgname=('efl' 'efl_doc')
pkgver=@VERSION@
pkgrel=1
pkgdesc="Enlightenment Foundation Libraries - GIT development snapshot (Ecore, Eldbus, Edje, Eet, Eeze, Efreet, Eina, Eio, Embryo, Emotion, Eo, Ephysics, Ethumb, & Evas)"
arch=('i686' 'x86_64' 'arm')
url="http://www.enlightenment.org"
license=('BSD' 'LGPL2.1' 'GPL2' 'custom')
makedepends=('doxygen' 'check')
depends=('bullet' 'libpng' 'libjpeg-turbo' 'gstreamer0.10'
         'gstreamer0.10-base' 'gstreamer0.10-good'
         'gstreamer0.10-bad' 'gstreamer0.10-ugly' 'gstreamer0.10-ffmpeg'
         'zlib' 'lua' 'libtiff' 'openssl' 'util-linux' 'curl' 'dbus'
         'glibc' 'fontconfig' 'freetype2' 'fribidi' 'libpulse'
         'libsndfile' 'systemd' 'libx11' 'libxau' 'libxcomposite'
         'libxdamage' 'libxdmcp' 'libxext' 'libxfixes' 'libxinerama'
         'libxi' 'libxrandr' 'libxrender' 'libxss' 'libxtst'
         'libxcursor' 'libxp' 'libgl' 'giflib' 'libwebp' 'harfbuzz')
provides=("ecore=$pkgver" "eldbus=$pkgver" "edje=$pkgver"
          "eet=$pkgver" "eeze=$pkgver" "efreet=$pkgver"
          "eina=$pkgver" "eio=$pkgver" "embryo=$pkgver" "emotion=$pkgver"
          "ephysics=$pkgver" "ethumb=$pkgver" "evas=$pkgver")
conflicts=('ecore' 'edje' 'eet' 'eeze' 'efreet' 'eina' 'eio' 'embryo' 'emotion'
           'ethumb' 'evas')
options=('!libtool' 'debug')
install=efl.install

prepare() {
  sed -i 's/env python$/&2/' "../../src/scripts/eina/eina-bench-cmp"
}

build() {
  cd "../.."
  export CFLAGS="$CFLAGS -fvisibility=hidden -fomit-frame-pointer"
  export CXXFLAGS="$CXXFLAGS -fvisibility=hidden -fomit-frame-pointer"
  [[ -e Makefile ]] && make clean distclean
  ./configure --prefix=/usr \
  --disable-static --disable-tslib --enable-fb \
  --enable-xinput22 --enable-multisense --enable-systemd \
  --enable-image-loader-webp --enable-harfbuzz
  make
  make -j1 doc
}

#check() {
#  cd "../.."
#  make -k check
#}

package_efl() {
  cd "../.."
  make -j1 DESTDIR="$pkgdir/" install
  install -Dm644 README "$pkgdir/usr/share/$pkgname/README"
  install -Dm644 NEWS "$pkgdir/usr/share/$pkgname/NEWS"
  install -Dm644 ChangeLog "$pkgdir/usr/share/$pkgname/ChangeLog"
  install -Dm644 AUTHORS "$pkgdir/usr/share/$pkgname/AUTHORS"
  install -Dm644 COMPLIANCE "$pkgdir/usr/share/$pkgname/COMPLIANCE"
  install -Dm644 licenses/COPYING.BSD "$pkgdir/usr/share/licenses/$pkgname/COPYING.BSD"
  install -Dm644 licenses/COPYING.GPL "$pkgdir/usr/share/licenses/$pkgname/COPYING.GPL"
  install -Dm644 licenses/COPYING.LGPL "$pkgdir/usr/share/licenses/$pkgname/COPYING.LGPL"
  install -Dm644 licenses/COPYING.SMALL "$pkgdir/usr/share/licenses/$pkgname/COPYING.SMALL"
  ln -s "../licenses/$pkgname/COPYING.BSD" "$pkgdir/usr/share/$pkgname/COPYING.BSD"
  ln -s "../licenses/$pkgname/COPYING.GPL" "$pkgdir/usr/share/$pkgname/COPYING.GPL"
  ln -s "../licenses/$pkgname/COPYING.LGPL" "$pkgdir/usr/share/$pkgname/COPYING.LGPL"
  ln -s "../licenses/$pkgname/COPYING.SMALL" "$pkgdir/usr/share/$pkgname/COPYING.SMALL"
}

package_efl_doc() {
  pkgdesc="Documentation for the Enlightenment Foundation Libraries"
  arch=('any')
  unset license depends provides conflicts install
  cd "../.."
  mkdir -p "$pkgdir/usr/share/doc/$pkgname"
  cp -a doc/html "$pkgdir/usr/share/doc/$pkgname/html"
  cp -a doc/latex "$pkgdir/usr/share/doc/$pkgname/latex"
}