summaryrefslogtreecommitdiff
path: root/src/lib/efl/interfaces/efl_pack_grid.eo
blob: 1f1f21fbce17234d7dd1d1997c81e6a941389e07 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
import efl_gfx_types;

interface Efl.Pack.Grid (Efl.Pack.Linear)
{
   [[2D containers aligned on a grid with rows and columns]]
   eo_prefix: efl_pack;
   methods {
      pack_grid {
      	 [[Pack object on the grid]]
         params {
            subobj: own(Efl.Gfx); [[Object]]
            col: int; [[Column number]]
            row: int; [[Row number]]
            colspan: int @optional; [[0 means 1, -1 means @.grid_columns]]
            rowspan: int @optional; [[0 means 1, -1 means @.grid_rows]]
         }
         return: bool; [[$true on success, $false otherwise]]
      }
      grid_contents_get {
         [[Returns all objects at a given position in this grid.]]
         return: free(own(iterator<Efl.Gfx>), eina_iterator_free); [[Iterator to grid contents]]
         params {
            @in col: int; [[Column number]]
            @in row: int; [[Row number]]
            @in below: bool @optional; [[If $true get objects spanning over this cell.]]
         }
      }
      grid_content_get {
         [[Returns a child at a given position, see @.grid_contents_get.]]
         return: Efl.Gfx; [[Child object]]
         params {
            @in col: int; [[Column number]]
            @in row: int; [[Row number]]
         }
      }
      @property grid_position {
         [[Position and span of the $subobj in this container, may be modified to move the $subobj]]
         get { return: bool; [[Returns false if item is not a child]] }
         keys {
            subobj: Efl.Gfx; [[Child object]]
         }
         values {
            col: int; [[Column number]]
            row: int; [[Row number]]
            colspan: int; [[Column span]]
            rowspan: int; [[Row span]]
         }
      }
      @property grid_size {
         [[Combines @.grid_columns and @.grid_rows]]
         set {}
         get {}
         values {
            cols: int; [[Number of columns]]
            rows: int; [[Number of rows]]
         }
      }
      @property grid_columns {
      	 [[Gird columns property]]
         set { [[Specifies limit for linear adds - if direction is horizontal]] }
         get {}
         values {
            cols: int; [[Number of columns]]
         }
      }
      @property grid_rows {
      	 [[Grid rows property]]
         set { [[Specifies limit for linear adds - if direction is vertical]] }
         get {}
         values {
            rows: int; [[Number of rows]]
         }
      }
      @property grid_direction {
         [[Primary and secondary up/left/right/down directions for linear apis.

           Default is horizontal and vertical.
           This overrides @Efl.Ui.Direction.direction.
         ]]
         set {}
         get {}
         values {
            primary: Efl.Ui.Dir(Efl.Ui.Dir.horizontal); [[Primary direction]]
            secondary: Efl.Ui.Dir(Efl.Ui.Dir.vertical); [[Secondary direction]]
         }
      }
   }
}