summaryrefslogtreecommitdiff
path: root/src/lib/emile/meson.build
blob: d8734cd1f257a5c028af1bfcc21410d101310c69 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
emile_deps = [jpeg, crypto, dependency('zlib')]
emile_pub_deps = [eina, efl]

emile_headers = [
  'Emile.h',
  'emile_cipher.h',
  'emile_compress.h',
  'emile_image.h',
  'emile_base64.h'
]

emile_src = [
  'emile_private.h',
  'emile_main.c',
  'emile_compress.c',
  'emile_image.c',
  'emile_base64.c',
]

if (get_option('crypto') == 'gnutls')
  emile_src += 'emile_cipher_gnutls.c'
elif (get_option('crypto') == 'openssl')
  emile_src += 'emile_cipher_openssl.c'
endif

emile_lib = library('emile',
    emile_src,
    c_args : package_c_args,
    include_directories: config_dir,
    dependencies: emile_pub_deps + emile_deps + [lz4, rg_etc, m],
    install: true,
    version : meson.project_version()
)

emile = declare_dependency(
  include_directories: include_directories('.'),
  link_with: emile_lib,
  dependencies: [eina, efl],
)

install_headers(emile_headers,
  install_dir: dir_package_include
)