summaryrefslogtreecommitdiff
path: root/PKGBUILD
blob: 4ab01b1a825beca9dc659c367d12841713983ced (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
# Maintainer: Emmanuel Gil Peyrot <emmanuel.peyrot@collabora.com>
# Changes from: Felipe Magno de Almeida <felipe@expertise.dev>

_pkgname=git-phab
pkgname=git-phab-efl-git
pkgver=r188.a364d8d
pkgrel=1
pkgdesc="Git subcommand to integrate with phabricator"
arch=('any')
url='https://pypi.org/project/git-phab/'
license=('GPL2')
depends=('python-gitpython' 'python-phabricator' 'python-argcomplete' 'python-appdirs')
provides=("$_pkgname")
conflicts=("$_pkgname")
makedepends=('git' 'asciidoc')
source=("$_pkgname::git+https://git.enlightenment.org/devs/zmike/git-phab.git")
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/$_pkgname"
  echo "r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

build() {
  cd "$srcdir/$_pkgname"
  a2x --doctype manpage --format manpage git-phab.txt
}

package() {
  cd "$srcdir/$_pkgname"
  install -Dm755 git-phab "$pkgdir/usr/bin/$_pkgname"
  install -Dm644 git-phab.1 "$pkgdir/usr/share/man/man1/$_pkgname.1"
  install -Dm644 README.md "$pkgdir/usr/share/doc/$_pkgname/README"
}