# Maintainer: Enlightenment Developers <enlightenment-devel@enlightenment.org>
pkgname=('elementary' 'elementary_test' 'elementary_doc')
pkgver=@VERSION@
pkgrel=1
pkgdesc="Enlightenment GUI toolkit - GIT development snapshot"
arch=('i686' 'x86_64' 'arm')
url="http://www.enlightenment.org"
license=('LGPL2.1' 'CCPL:cc-by-sa')
makedepends=('doxygen' 'imagemagick')
depends=('efl_x11' 'evas_generic_loaders')
optdepends=('emotion_generic_players')
options=('!libtool' 'debug')
build() {
  cd "../.."
  export CFLAGS="$CFLAGS -fvisibility=hidden -fomit-frame-pointer"
  make clean distclean
  ./configure --prefix=/usr \
  --disable-static
  make
  make doc
}

#check() {
#  cd "../.."
#  make -k check
#}

package_elementary() {
  cd "../.."
  make -j1 DESTDIR="$pkgdir/" install
  install -Dm644 README "$pkgdir/usr/share/$pkgname/README"
  install -Dm644 NEWS "$pkgdir/usr/share/$pkgname/NEWS"
  install -Dm644 ChangeLog "$pkgdir/usr/share/$pkgname/ChangeLog"
  install -Dm644 AUTHORS "$pkgdir/usr/share/$pkgname/AUTHORS"
  install -Dm644 COMPLIANCE "$pkgdir/usr/share/$pkgname/COMPLIANCE"
  install -Dm644 COPYING.images "$pkgdir/usr/share/licenses/$pkgname/COPYING.images"
  sed -n '1,/details./p' COPYING > "$pkgdir/usr/share/licenses/$pkgname/COPYING"
  ln -s "../licenses/$pkgname/COPYING" "$pkgdir/usr/share/$pkgname/COPYING"
  ln -s "../licenses/$pkgname/COPYING.images" "$pkgdir/usr/share/$pkgname/COPYING.images"
  rm -rf "$pkgdir/usr/bin/"elementary_test*
  rm -rf "$pkgdir/usr/lib/elementary/modules/"{test_entry,test_map}
  rm -rf "$pkgdir/usr/lib/elementary_testql.so"
  rm -rf "$pkgdir/usr/share/applications/elementary_test.desktop"
  rm -rf "$pkgdir/usr/share/elementary/"{examples,images,objects}
}

package_elementary_test() {
  pkgdesc="Test application for Elementary"
  depends=('elementary')

  cd "../.."
  make -j1 DESTDIR="$pkgdir/" install
  rm -rf "$pkgdir/usr/include"
  rm -rf "$pkgdir/usr/bin/"{elementary_codegen,elementary_config,elementary_quicklaunch,elementary_run,elm_prefs_cc}
  rm -rf "$pkgdir/usr/lib/"{cmake,edje,elementary,libelementary.so*,pkgconfig}
  rm -rf "$pkgdir/usr/share/applications/elementary_config.desktop"
  rm -rf "$pkgdir/usr/share/elementary/"{config,examples,themes,edje_externals}
  rm -rf "$pkgdir/usr/share/"{icons,locale}
}

package_elementary_doc() {
  pkgdesc="Documentation for Elementary"
  depends=()

  cd "../.."
  mkdir -p "$pkgdir/usr/share/$pkgname"
  cp -a doc/html "$pkgdir/usr/share/$pkgname/html"
  cp -a doc/latex "$pkgdir/usr/share/$pkgname/latex"
}