efl/data/elementary/themes/edc/elm/fileselector.edc

group { name: "elm/entry/path/separator/default";
   images.image: "sym_right_glow_normal.png" COMP;
   parts {
      image { "icon"; nomouse;
         desc { "default";
            image.normal: "sym_right_glow_normal.png";
            FIXED_SIZE(15, 15)
            aspect: 1.0 1.0;
         }
      }
   }
}

group { name: "elm/fileselector/base/default";
   data.item: "path_separator" "<item relsize=15x15 vsize=full href=path/separator></item>";
   parts {
      swallow { "elm.swallow.up";
         desc { "default";
            align: 0.0 0.0;
            fixed: 1 1;
            rel1.offset: 3 3;
            rel2.relative: 0.0 0.0;
            rel2.offset: 3 3;
         }
      }
      swallow { "elm.swallow.home";
         desc { "default";
            align: 0.0 0.5;
            fixed: 1 0;
            rel1 {
               to: "elm.swallow.up";
               relative: 1.0 0.0;
               offset: 3 0;
            }
            rel2 {
               to: "elm.swallow.up";
               relative: 1.0 1.0;
               offset: 3 -1;
            }
         }
      }
      swallow { "elm.swallow.search";
         desc { "default";
            align: 0.0 0.5;
            min: 65 0;
            fixed: 0 1;
            rel1 {
               to: "elm.swallow.home";
               relative: 1.0 0.0;
               offset: 3 0;
            }
            rel2 {
               to_y: "elm.swallow.home";
               relative: 1.0 1.0;
               offset: -4 -1;
            }
         }
      }
#ifdef ELM_CANCEL_OK
      swallow { "elm.swallow.ok";
#else
      swallow { "elm.swallow.cancel";
#endif
         desc { "default";
            align: 1.0 1.0;
            fixed: 1 1;
            rel1.relative: 1.0 1.0;
            rel1.offset: -4 -4;
            rel2.relative: 1.0 1.0;
            rel2.offset: -4 -4;
         }
      }
#ifdef ELM_CANCEL_OK
      swallow { "elm.swallow.cancel";
#else
      swallow { "elm.swallow.ok";
#endif
         desc { "default";
            align: 1.0 0.5;
            fixed: 1 0;
            rel1 {
#ifdef ELM_CANCEL_OK
               to: "elm.swallow.ok";
#else
               to: "elm.swallow.cancel";
#endif
               relative: 0.0 0.0;
               offset: -4 0;
            }
            rel2 {
#ifdef ELM_CANCEL_OK
               to: "elm.swallow.ok";
#else
               to: "elm.swallow.cancel";
#endif
               relative: 0.0 1.0;
               offset: -4 -1;
            }
         }
      }
      swallow { "elm.swallow.filters";
         desc { "default";
            align: 1.0 1.0;
            fixed: 1 1;
            rel1 {
               to_y: "elm.swallow.ok";
               relative: 1.0 0.0;
               offset: -4 -4;
            }
            rel2 {
               to_y: "elm.swallow.ok";
               relative: 1.0 0.0;
               offset: -4 -4;
            }
         }
      }
      swallow { "elm.swallow.filename";
         desc { "default";
            align: 0.5 1.0;
            fixed: 0 1;
            rel1 {
               to_y: "elm.swallow.filters";
               relative: 0.0 0.0;
               offset: 3 -4;
            }
            rel2 {
               to_y: "elm.swallow.filters";
               relative: 1.0 0.0;
               offset: -4 -4;
            }
         }
      }
      swallow { "elm.swallow.path";
         desc { "default";
            align: 0.5 1.0;
            fixed: 0 1;
            rel1 {
               to_y: "elm.swallow.filename";
               relative: 0.0 0.0;
               offset: 3 -4;
            }
            rel2 {
               to_y: "elm.swallow.filename";
               relative: 1.0 0.0;
               offset: -4 -4;
            }
         }
      }
      swallow { "elm.swallow.files";
         desc { "default";
            rel1 {
               to_y: "elm.swallow.home";
               relative: 0.0 1.0;
               offset: 3 3;
            }
            rel2 {
               to_y: "elm.swallow.path";
               relative: 1.0 0.0;
               offset: -4 -4;
            }
         }
      }
      swallow { "elm.swallow.spinner";
         clip: "elm.spinner.clip";
         desc { "default";
            fixed: 1 1;
            align: 1.0 0.0;
            rel1.relative: 1.0 0.0;
            rel1.offset: -4 3;
            rel2.relative: 1.0 0.0;
            rel2.offset: -4 3;
         }
      }
      rect { "elm.spinner.clip";
         desc { "default";
            fixed: 1 1;
            rel1.to: "elm.swallow.spinner";
            rel2.to: "elm.swallow.spinner";
            color: 255 255 255 0;
         }
         desc { "visible";
            inherit: "default" 0.0;
            color: 255 255 255 255;
         }
      }
   }
   programs {
      program {
         signal: "elm,action,spinner,show"; source: "elm";
         action: STATE_SET "visible" 0.0;
         transition: LINEAR 0.2;
         target: "elm.spinner.clip";
      }
      program {
         signal: "elm,action,spinner,hide"; source: "elm";
         action: STATE_SET "default" 0.0;
         transition: LINEAR 0.5 CURRENT;
         target: "elm.spinner.clip";
      }
//      program {
//         signal: "elm,state,save,on"; source: "elm";
//      }
//      program {
//         signal: "elm,state,save,off"; source: "elm";
//      }
   }
}

group { name: "elm/fileselector_entry/base/default";
   parts {
      swallow { "elm.swallow.button"; scale;
         desc { "default";
            align: 1.0 0.0;
            fixed: 1 0;
            min: 40 4;
            rel1 {
               relative: 1.0 0.0;
               offset: -1 0;
            }
         }
      }
      swallow { "elm.swallow.entry"; scale;
         desc { "default";
            align: 0.0 0.5;
            min: 50 4;
            rel2 { to_x: "elm.swallow.button";
               relative: 0.0 1.0;
               offset: -1 -1;
            }
         }
      }
   }
}