#### Project ####
project('extramenu', 'c',
        version: '0.3.0',
        license: 'GPL v3',
        meson_version: '>= 0.47.0')


#### Enlightenemnt ####
dep_e = dependency('enlightenment')
e_modules_dir = dep_e.get_pkgconfig_variable('modules')
e_release = dep_e.get_pkgconfig_variable('release')


#### Host arch ####
host_os = host_machine.system()
if host_os == 'linux'
   cc = meson.get_compiler('c')
   if cc.has_header_symbol('features.h', '__UCLIBC__')
      host_os = 'linux-uclibc'
   elif cc.has_header_symbol('features.h', '__dietlibc__')
      host_os = 'linux-dietlibc'
   else
      host_os = 'linux-gnu'
   endif
endif
mod_arch = '@0@-@1@-@2@'.format(host_os, host_machine.cpu_family(), e_release)


#### Install dirs ####
mod_install_dir = join_paths(e_modules_dir, meson.project_name())
lib_install_dir = join_paths(mod_install_dir, mod_arch)


#### config.h ####
config_h = configuration_data()
config_h.set_quoted('PACKAGE', meson.project_name())
config_dir = include_directories('.')


#### Edje cc ####
edje_cc = find_program('edje_cc')


#### module sources ####
subdir('src')


#### write config file ####
configure_file(output: 'extramenu_config.h', configuration: config_h)


#### Data files ####
install_data('module.desktop', install_dir: mod_install_dir)

cmd = [edje_cc,
       '-id', meson.source_root(),
       '@INPUT@', '@OUTPUT@']
custom_target('e-module-extramenu.edj',
              input      : 'e-module-extramenu.edc',
              output     : 'e-module-extramenu.edj',
              command    : cmd,
              install_dir: mod_install_dir,
              install    : true
             )