efl/src/lib/evas/canvas/evas_textgrid.eo

class Evas.Textgrid (Evas.Object, Efl.Text_Properties)
{
   legacy_prefix: evas_object_textgrid;
   eo_prefix: evas_obj_textgrid;
   methods {
      @property supported_font_styles {
         set {
            /*@
            This function is not implemented yet, do not use. */
         }
         get {
            /*@
            This function is not implemented yet, do not use.
            @return EVAS_TEXTGRID_FONT_STYLE_NORMAL */
         }
         values {
            styles: Evas_Textgrid_Font_Style;
         }
      }
      @property size {
         set {
            /*@
            @brief Set the size of the textgrid object.

            This function sets the number of lines @p h and the number
            of columns @p w to the textgrid object @p obj. If
            @p w or @p h are less or equal than 0, this
            functiond does nothing.

            @since 1.7 */
         }
         get {
            /*@
            @brief Get the size of the textgrid object.

            This function retrieves the number of lines in the buffer @p
            h and the number of columns in the buffer @p w of
            the textgrid object @p obj. @p w or @p h can be
            @c NULL. On error, their value is 0.

            @since 1.7 */
         }
         values {
            w: int; /*@ The number of columns (width in cells) of the grid. */
            h: int; /*@ The number of rows (height in cells) of the grid. */
         }
      }
      @property cell_size {
         get {
            /*@
            @brief Retrieve the size of a cell of the given textgrid object in pixels.

            This functions retrieves the width and height, in pixels, of a cell
            of the textgrid object @p obj and store them respectively in the
            buffers @p width and @p height. Their value depends on the
            monospace font used for the textgrid object, as well as the
            style. @p width and @p height can be @c NULL. On error, they are
            set to 0.

            @see evas_object_textgrid_font_set()
            @see evas_object_textgrid_supported_font_styles_set()

            @since 1.7 */
         }
         values {
            width: int; /*@ A pointer to the location to store the width in pixels of a cell. */
            height: int; /*@ A pointer to the location to store the height in
            pixels of a cell. */
         }
      }
      update_add {
         /*@
         @brief Indicate for evas that part of a textgrid region (cells) has been updated.

         This function declares to evas that a region of cells was updated by
         code and needs refreshing. An application should modify cells like this
         as an example:

         @code
         Evas_Textgrid_Cell *cells;
         int i;

         cells = evas_object_textgrid_cellrow_get(obj, row);
         for (i = 0; i < width; i++) cells[i].codepoint = 'E';
         evas_object_textgrid_cellrow_set(obj, row, cells);
         evas_object_textgrid_update_add(obj, 0, row, width, 1);
         @endcode

         @see evas_object_textgrid_cellrow_set()
         @see evas_object_textgrid_cellrow_get()
         @see evas_object_textgrid_size_set()

         @since 1.7 */
   
         params {
            @in x: int; /*@ The rect region of cells top-left x (column) */
            @in y: int; /*@ The rect region of cells top-left y (row) */
            @in w: int; /*@ The rect region size in number of cells (columns) */
            @in h: int; /*@ The rect region size in number of cells (rows) */
         }
      }
      cellrow_set {
         /*@
         @brief Set the string at the given row of the given textgrid object.

         This function returns cells to the textgrid taken by
         evas_object_textgrid_cellrow_get(). The row pointer @p row should be the
         same row pointer returned by evas_object_textgrid_cellrow_get() for the
         same row @p y.

         @see evas_object_textgrid_cellrow_get()
         @see evas_object_textgrid_size_set()
         @see evas_object_textgrid_update_add()

         @since 1.7 */

         params {
            @in y: int; /*@ The row index of the grid. */
            @in row: const(Evas_Textgrid_Cell)*; /*@ The string as a sequence of #Evas_Textgrid_Cell. */
         }
      }
      cellrow_get @const {
         /*@
         @brief Get the string at the given row of the given textgrid object.

         @return A pointer to the first cell of the given row.

         This function returns a pointer to the first cell of the line @p y
         of the textgrid object @p obj. If @p y is not between 0 and the
         number of lines of the grid - 1, or on error, this function return @c NULL.

         @see evas_object_textgrid_cellrow_set()
         @see evas_object_textgrid_size_set()
         @see evas_object_textgrid_update_add()

         @since 1.7 */
         return: Evas_Textgrid_Cell*;
         params {
            @in y: int; /*@ The row index of the grid. */
         }
      }
      palette_set {
         /*@
         @brief The set color to the given palette at the given index of the given textgrid object.

         This function sets the color for the palette of type @p pal at the
         index @p idx of the textgrid object @p obj. The ARGB components are
         given by @p r, @p g, @p b and @p a. This color can be used when
         setting the #Evas_Textgrid_Cell structure. The components must set
         a pre-multiplied color. If pal is #EVAS_TEXTGRID_PALETTE_NONE or
         #EVAS_TEXTGRID_PALETTE_LAST, or if @p idx is not between 0 and 255,
         or on error, this function does nothing. The color components are
         clamped between 0 and 255. If @p idx is greater than the latest set
         color, the colors between this last index and @p idx - 1 are set to
         black (0, 0, 0, 0).

         @see evas_object_textgrid_palette_get()

         @since 1.7 */

         params {
            @in pal: Evas_Textgrid_Palette; /*@ The type of the palette to set the color. */
            @in idx: int; /*@ The index of the paletter to which the color is stored. */
            @in r: int; /*@ The red component of the color. */
            @in g: int; /*@ The green component of the color. */
            @in b: int; /*@ The blue component of the color. */
            @in a: int; /*@ The alpha component of the color. */
         }
      }
      palette_get @const {
         /*@
         @brief The retrieve color to the given palette at the given index of the given textgrid object.

         This function retrieves the color for the palette of type @p pal at the
         index @p idx of the textgrid object @p obj. The ARGB components are
         stored in the buffers @p r, @p g, @p b and @p a. If @p idx is not
         between 0 and the index of the latest set color, or if @p pal is
         #EVAS_TEXTGRID_PALETTE_NONE or #EVAS_TEXTGRID_PALETTE_LAST, the
         values of the components are 0. @p r, @p g, @p b and @p a can be
         @c NULL.

         @see evas_object_textgrid_palette_set()

         @since 1.7 */
         params {
            @in pal: Evas_Textgrid_Palette; /*@ The type of the palette to set the color. */
            @in idx: int; /*@ The index of the palette to which the color is stored. */
            @out r: int; /*@ A pointer to the red component of the color. */
            @out g: int; /*@ A pointer to the green component of the color. */
            @out b: int; /*@ A pointer to the blue component of the color. */
            @out a: int; /*@ A pointer to the alpha component of the color. */
         }
      }
   }
   implements {
      Eo.Base.constructor;
      Eo.Base.destructor;
      Eo.Base.dbg_info_get;
      Efl.Text_Properties.font.get;
      Efl.Text_Properties.font.set;
      Efl.Text_Properties.font_source.get;
      Efl.Text_Properties.font_source.set;
   }
}